WS2812B七彩LED具有集成度高、使用方便等特点，但是800K的数据速率（IO变化速率高达2.4M），对单片机提出了较高的要求，通常是采用SPI+DMA方式驱动，

也有人采用汇编实现，但是要预先把数据转换为按bit存放，在LED级连数量较多的情况下，需要占用极多的存储空间。

在驱动WS2812B上花费了太多的时间，走了不少弯路，记录下来：

简易数字分析仪采样频率最高只有4M，即测量精度为250ns，而信号宽度要求为400ns和850ns，这样测量的结果存在较大的误差，让人误以为信号跳变无规律，
迷失了方向；解决的办法就是利用STC单片机主时钟的内分频功能，语句：CLK_DIV |= 0x07; 将主频降低128倍，这样测量的波形就足够准确了。 STC15系列可以使用内置振荡电路，主频高达27M，高速才有足够的时间进行数据处理，最终选择的是24M的主频。 汇编与C混合编程，开始以为很复杂，做了发现不是很困难，主要还是对汇编本身的理解。
1、形式上，在C语言中通过#pragma ASM和#pragma ENDASM内嵌汇编语句；
2、编译器在使用内嵌语句的文件右键菜单选择Option，选中Generate assembler SRC file 和 assemble SRC file；
3、子程序调用时的参数传递上，一般是用R7，R5，R3，具体可以看编译生成的SRC文件； 最初采用高级语言的两层循环嵌套，内层通过移位实现8个比特输出，外层依次处理每个比特，但是两层循环之间的时延较长，导致输出的波形不规则；
最终打破结构化编程的框架，利用每个比特中850ns输出的长信号进行数据处理，实现了完美波形输出； 在LED数量较多的情况下，发现会有闪烁，经常时间的查找，最后判断是信号输出期间产生硬件中断，导致输出的波形有跳变，导致不特定位置的LED出现闪烁；

128分频下的输出波形

源代码：

void WS2812_SendArray(uchar xdata *pSource, uchar length) {
EA = 0;
#pragma ASM
CLR WS5050_DI
MOV R1,#160
SA_DELAY25:
DJNZ R1, SA_DELAY25
MOV R1,#160
SA_DELAY25_2:
DJNZ R1, SA_DELAY25_2

; R5:length, R1:8bit, R4:临时存储A
MOV DPH, R6
MOV DPL, R7
MOVX A, @DPTR
MOV R1,#8 ;2
SA_BIT_PHASE0:
SETB WS5050_DI ;4
NOP ;1
RLC A ;1
JC SA_BIT_1 ;3
NOP ;1
CLR WS5050_DI ;4
CJNE R1, #1, SA_BIT0_NOT8 ;4
; 当寄存器R1=1，说明是最后一位，则准备下一字节
INC DPTR ;1
MOVX A, @DPTR ;2
MOV R1,#9 ;2
DJNZ R5, SA_PHASE3 ;4
; R5=0,结束
SJMP SA_END ;3
SA_BIT0_NOT8:
; R1>1,前七位
XCH A, R4 ;2
MOVX A, @DPTR ;2
XCH A, R4 ;2
NOP
SJMP SA_PHASE3 ;3
SA_BIT_1:
CJNE R1, #1, SA_BIT1_NOT8 ;4
; 当寄存器R1=1，说明是最后一位，则准备下一字节
INC DPTR ;1
MOVX A, @DPTR ;2
MOV R1,#9 ;2
NOP
DJNZ R5, SA_BIT1_9TH ;4
; R5=0,结束
SJMP SA_END ;3
SA_BIT1_NOT8:
XCH A, R4 ;2
MOVX A, @DPTR ;2
XCH A, R4 ;2
NOP
NOP
NOP
SA_BIT1_9TH:
CLR WS5050_DI
NOP ;1
NOP ;1
SA_PHASE3:
DJNZ R1, SA_BIT_PHASE0 ;4

SA_END:
SETB WS5050_DI
#pragma ENDASM
EA = 1;
pSource = 0;
length = 0;
}